Feature Request: Custom themes in btop module

[ItsLiyua]

btop can only load themes from $HOME/.config/btop/themes or ../share/btop/themes/ relative to the executable by default.
Additionally there is a flag to specify a custom theme directory.

I'd like to have an option that allows me to specify a custom location for themes so I can pass in a custom style for my btop wrapper.

[Hythera]

I have this for my personal setup if it helps. It exposes a themes and themeFiles attribute . Some of it is based on the home-manager implementation :)

{
  self,
  inputs,
  ...
}:
{
  perSystem =
    {
      pkgs,
      ...
    }:
    {
      packages.btop =
        (self.wrapperModules.btop.apply {
          inherit pkgs;
          settings = {
            color_theme = "TTY";
            theme_background = false;
          };
          themes = {
            my-theme = ''
               theme[main_bg]="#282a36"
               theme[main_fg]="#f8f8f2"
               theme[title]="#f8f8f2"
               ...
            '';
          };
        }).wrapper;
    };
  flake.wrapperModules.btop = inputs.wrappers.lib.wrapModule (
    {
      config,
      lib,
      wlib,
      ...
    }:
    let
      inherit (lib)
        mapAttrsToList
        mkOption
        types
        ;
      inherit (lib.generators) mkKeyValueDefault;
      btopKeyValueFormat = config.pkgs.formats.keyValue {
        mkKeyValue = mkKeyValueDefault {
          mkValueString =
            v:
            with builtins;
            if isBool v then
              (if v then "True" else "False")
            else if isString v then
              ''"${v}"''
            else
              toString v;
        } " = ";
      };
      writeBtopConfig = cfg: btopKeyValueFormat.generate "btop.conf" cfg;
    in
    {
      config = {
        flags = {
          "-c" = config.configFile.path;
          "--themes-dir" =
            (config.pkgs.linkFarm "themes" (
              mapAttrsToList (name: value: {
                inherit (value) path;
                name = "${name}.theme";
              }) config.themeFiles
            )).outPath;
        };

        package = config.pkgs.btop;
      };

      options = {
        configFile = mkOption {
          default.path = toString (writeBtopConfig config.settings) + config.extraConfig;
          type = wlib.types.file config.pkgs;
        };

        extraConfig = mkOption {
          default = "";
          type = types.str;
        };

        settings = mkOption {
          default = { };
          type =
            with types;
            attrsOf (oneOf [
              bool
              float
              int
              str
            ]);
        };

        themeFiles = mkOption {
          default = builtins.mapAttrs (name: value: {
            path = toString (config.pkgs.writeText name value);
          }) config.themes;
          type = types.attrsOf (wlib.types.file config.pkgs);
        };

        themes = mkOption {
          default = { };
          type = types.attrsOf types.lines;
        };
      };
    }
  );
}

[ItsLiyua]

Sorry for taking so long to respond. That looks interesting. I'll try setting that up for myself. Can we get something like this natively?

[Hythera]

I can create a PR with the additions when I have the time to do so. Also feel free to submit one yourself before that that is based on my changes.

[altacountbabi]

     themes = {
       my-theme = ''
          theme[main_bg]="#282a36"
          theme[main_fg]="#f8f8f2"
          theme[title]="#f8f8f2"
          ...
       '';
     };

why not use an attrset for this? you could skip the theme[] part too

[Hythera]

Why not use an attrset for this? you could skip the theme[] part too.

This is of course possible and might be better. I just want to have a simple way of declaring themes in a copy-paste style so I don't have to convert already existing themes to attribute sets. This would of course still be possible when exposing a wrappers lib file type (which is done in this example), but I didn't bother adding the conversion.