Redshift-OSL-Shaders/MarbleVeinNoise.osl at main · Maxon-Computer/Redshift-OSL-Shaders · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
// Created by Saul Espinosa for Redshift 3D
// Based on  * LGVeinedMarble.osl by Shane Ambler
// Modified 01.11.2022
// This file is licensed under Apache 2.0 license

shader MarbleVeinNoise
[[  string help = "Marble Vein Noise Generator",
    string label = "Marble Vein Noise" ]]
(

// Input Paramaters

        color diffuse_color = 0.0
		[[
			string label = "Base Color",
			string page = "Base"
		]],

		color VeinColor = 1.0
		[[
			string label = "Vein Color",
			string page = "Marble Vein"
		]],
        float VeinFreq = 1.0
		[[
			string label = "Vein Frequency" ,
			string page = "Marble Vein",
			float min = 0, float max = 10
		]],
        float VeinLevels = 2.0
		[[
			string label = "Vein Levels" ,
			string page = "Marble Vein",
			float min = 0, float max = 25
		]],
        float WarpFreq = 1.0
		[[
			string label = "Warp Frequency" ,
			string page = "Marble Vein",
			float min = 0, float max = 25
		]],
        float Warping = 0.5
		[[
			string label = "Vein Warping" ,
			string page = "Marble Vein",
			float min = 0, float max = 25
		]],
        float Sharpness = 8.0
		[[
			string label = "Vein Sharpness" ,
			string page = "Marble Vein",
			float min = 0, float max = 25
		]],
		int Space = 1
		[[
			string page = "Co-ordinates",
			string widget = "mapper",
			string options = "World:0|Object:1|Fixed:2",
			int connectable = 0
		]],
		vector Origin = 0
		[[
			string page = "Co-ordinates",
		]],

// Output Noise
    output color outColor = 1

)

{
// Define Noise
#define snoise(x) (2*noise(x)-1)
    color Ct;
    point Nf;
    point PP, offset;
    float i, turb, freq, j;
    float turbsum;

	if (Space == 0)
	    PP = P + Origin;
	else if (Space == 1)
		PP = transform("object", P) + Origin;
	else
		PP = Origin;

    /* perturb the lookup */
    freq = 1;
    offset = 0;
    for (i = 0;  i < 6;  i += 1) {
        offset += 2 * Warping * ( noise (WarpFreq * freq * PP) - 0.5)  / freq;
        freq *= 2;
    }
    PP += offset;

    /* Now calculate the veining function for the lookup area */
    turbsum = 0;  freq = 1;
    PP *= VeinFreq;
    for (i = 0;  i < VeinLevels;  i += 1) {
        turb = abs (snoise (PP));
        turb = pow (smoothstep (0.8, 1, 1 - turb), Sharpness) / freq;
        turbsum += (1-turbsum) * turb;
        freq *= 3;
        PP *= 3;
    }

// Output
    outColor = mix (diffuse_color, VeinColor, turbsum);
}