cmake(generator): Modernize generator build-system

- Leverages automatic execution of MOC and RCC.
- Removes obsolete install rules for `build_*.txt` and `typesystem_*.xml`.
- Uses "usage requirements" and aligns source lists with `parser/rxx.pro`,
  `simplecpp/simplecpp.pri`, `generator.pri`, and `generator.pro`.

Author: jcfr

generator/CMakeLists.txt

@@ -1,37 +1,29 @@
-cmake_minimum_required(VERSION 2.8)
+cmake_minimum_required(VERSION 3.20.6)
 
-#-----------------------------------------------------------------------------
-project(PythonQtGenerator)
-#-----------------------------------------------------------------------------
-
-include(CTestUseLaunchers OPTIONAL)
+project(PythonQtGenerator LANGUAGES CXX)
 
-#-----------------------------------------------------------------------------
+#----------------------------------------------------------------------------
 # Setup Qt
 
-set(minimum_required_qt_version "4.6.2")
-
-find_package(Qt4)
+# Set PythonQtGenerator_QT_VERSION
+set(PythonQtGenerator_QT_VERSION 5)
 
-if(QT4_FOUND)
+set(minimum_required_qt5_version "5.15.0")
+set(minimum_required_qt_version ${minimum_required_qt${PythonQtGenerator_QT_VERSION}_version})
 
-  set(found_qt_version ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH})
+set(qt_required_components Core Xml)
 
-  if(${found_qt_version} VERSION_LESS ${minimum_required_qt_version})
-      message(FATAL_ERROR "error: PythonQt requires Qt >= ${minimum_required_qt_version} -- you cannot use Qt ${found_qt_version}.")
-  endif()
+message(STATUS "${PROJECT_NAME}: Required Qt${PythonQtGenerator_QT_VERSION} components [${qt_required_components}]")
 
-  set(QT_USE_QTXML ON)
-
-  include(${QT_USE_FILE})
-else()
-  message(FATAL_ERROR "error: Qt4 was not found on your system. You probably need to set the QT_QMAKE_EXECUTABLE variable")
-endif()
+# Requirements
+find_package(Qt${PythonQtGenerator_QT_VERSION} ${minimum_required_qt_version}
+  COMPONENTS ${qt_required_components} REQUIRED)
 
 #-----------------------------------------------------------------------------
 # Sources
 
 set(sources
+  # Based of parser/rxx.pro
   parser/ast.cpp
   parser/binder.cpp
   parser/class_compiler.cpp
@@ -51,108 +43,62 @@ set(sources
   parser/type_compiler.cpp
   parser/visitor.cpp
 
+  # Based of simplecpp/simplecpp.pri
+  simplecpp/simplecpp.cpp
+
+  # Based of generator.pri
   abstractmetabuilder.cpp
   abstractmetalang.cpp
   asttoxml.cpp
   customtypes.cpp
   fileout.cpp
   generator.cpp
+  generator.qrc
   generatorset.cpp
-  generatorsetqtscript.cpp
   main.cpp
   metajava.cpp
-  metaqtscriptbuilder.cpp
-  metaqtscript.cpp
   prigenerator.cpp
   reporthandler.cpp
+  typeparser.cpp
+  typesystem.cpp
+
+  # Based of generator.pro
+  generatorsetqtscript.cpp
+  metaqtscriptbuilder.cpp
+  metaqtscript.cpp
   setupgenerator.cpp
   shellgenerator.cpp
   shellheadergenerator.cpp
   shellimplgenerator.cpp
-  typeparser.cpp
-  typesystem.cpp
   )
 
-#-----------------------------------------------------------------------------
-# List headers.  This list is used for the install command.
+add_executable(${PROJECT_NAME} ${sources})
 
-set(headers
+set_target_properties(${PROJECT_NAME}
+  PROPERTIES
+    AUTOMOC TRUE
+    AUTORCC TRUE
   )
 
-#-----------------------------------------------------------------------------
-# Headers that should run through moc
-
-set(moc_sources
-  fileout.h
-  generator.h
-  generatorset.h
-  generatorsetqtscript.h
-  prigenerator.h
-  setupgenerator.h
-  shellgenerator.h
-  shellheadergenerator.h
-  shellimplgenerator.h
+target_include_directories(${PROJECT_NAME}
+  PUBLIC
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/parser>
+    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/simplecpp>
   )
 
-#-----------------------------------------------------------------------------
-# UI files
-
-set(ui_sources )
-
-#-----------------------------------------------------------------------------
-# Resources
-
-set(qrc_sources
-  generator.qrc
+target_link_libraries(${PROJECT_NAME}
+  PUBLIC
+    Qt::Core
+    Qt::Xml
   )
 
-#-----------------------------------------------------------------------------
-# Do wrapping
-qt4_wrap_cpp(gen_moc_sources ${moc_sources})
-qt4_wrap_ui(gen_ui_sources ${ui_sources})
-qt4_add_resources(gen_qrc_sources ${qrc_sources})
-
-#-----------------------------------------------------------------------------
-# Copy file expected by the generator and specify install rules
-
-file(GLOB files_to_copy RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} "build_*.txt" "typesystem_*.xml")
-list(APPEND files_to_copy qtscript_masterinclude.h parser/rpp/pp-qt-configuration)
-foreach(file ${files_to_copy})
-  configure_file(
-    ${file}
-    ${CMAKE_CURRENT_BINARY_DIR}/${file}
-    COPYONLY
-    )
-  get_filename_component(destination_dir ${file} PATH)
-  install(FILES ${file} DESTINATION bin/${destination_dir})
-endforeach()
-
-#-----------------------------------------------------------------------------
-# Build the library
-
-SOURCE_GROUP("Resources" FILES
-  ${qrc_sources}
-  ${ui_sources}
-  ${files_to_copy}
+target_compile_definitions(${PROJECT_NAME}
+    PRIVATE
+      RXX_ALLOCATOR_INIT_0 # Based of parser/rxx.pro
+      QT_NO_CAST_TO_ASCII # Based of generator.pro
   )
 
-include_directories(
-  ${CMAKE_CURRENT_SOURCE_DIR}
-  ${CMAKE_CURRENT_SOURCE_DIR}/parser
-  ${CMAKE_CURRENT_SOURCE_DIR}/parser/rpp
-  )
-
-add_definitions(-DRXX_ALLOCATOR_INIT_0)
-
-add_executable(${PROJECT_NAME}
-  ${sources}
-  ${gen_moc_sources}
-  ${gen_ui_sources}
-  ${gen_qrc_sources}
-)
-
-target_link_libraries(${PROJECT_NAME} ${QT_LIBRARIES})
-
 #-----------------------------------------------------------------------------
 # Install library (on windows, put the dll in 'bin' and the archive in 'lib')