build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '4.1.0' apply false
    id 'io.spring.dependency-management' version '1.1.7' apply false
}

ext {
    querydslVersion = '7.4.0'
}

def applicationVersion = providers.gradleProperty('appVersion').get()

allprojects {
    group = 'com.nalssilog'
    version = applicationVersion
}

tasks.register('printVersion') {
    group = 'help'
    description = 'Prints the application release version.'

    doLast {
        println project.version
    }
}

subprojects {
    apply plugin: 'java-library'
    apply plugin: 'io.spring.dependency-management'

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(25)
        }
    }

    // @RequestParam/@PathVariable 등이 파라미터 이름을 리플렉션으로 읽을 수 있도록.
    // (Spring Boot 플러그인은 app 에만 붙어서 boot 미적용 모듈에는 자동 적용되지 않음)
    tasks.withType(JavaCompile).configureEach {
        options.compilerArgs.add('-parameters')
    }

    repositories {
        mavenCentral()
    }

    dependencyManagement {
        imports {
            mavenBom org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES
        }
    }

    dependencies {
        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'
        annotationProcessor "io.github.openfeign.querydsl:querydsl-apt:${querydslVersion}:jpa"
        annotationProcessor 'jakarta.persistence:jakarta.persistence-api'
        annotationProcessor 'jakarta.annotation:jakarta.annotation-api'

        testImplementation 'org.springframework.boot:spring-boot-starter-test'
        testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
        testCompileOnly 'org.projectlombok:lombok'
        testAnnotationProcessor 'org.projectlombok:lombok'
    }

    tasks.named('test') {
        useJUnitPlatform()
    }
}