[SUGGESTION] Color Pass Shader

[BouncyBonBon]

Something that works like Premiere Pro's color pass shader would be really useful. You should be able to set a hex code and an amount of variance from that hex code to accept through the filter and everything else becomes grayscale (or a set hue).

A couple of example images of what it should do that I stole from google:

[hizzlekizzle]

This was a fun little project. Thanks for suggesting it. It's in slang format, but here you go:

#version 450

layout(push_constant) uniform Push
{
	vec4 SourceSize;
	vec4 OriginalSize;
	vec4 OutputSize;
	uint FrameCount;
	float targetHue, hueThresh, desat;
} params;

#pragma parameter targetHue "Target Hue" 0.99 0.0 1.0 0.005
#pragma parameter hueThresh "Hue Difference Threshold" 0.15 0.0 1.0 0.005
#pragma parameter desat "Minimum Saturation" 0.0 0.0 1.0 0.01

layout(std140, set = 0, binding = 0) uniform UBO
{
	mat4 MVP;
} global;

#pragma stage vertex
layout(location = 0) in vec4 Position;
layout(location = 1) in vec2 TexCoord;
layout(location = 0) out vec2 vTexCoord;

void main()
{
   gl_Position = global.MVP * Position;
   vTexCoord = TexCoord;
}

#pragma stage fragment
layout(location = 0) in vec2 vTexCoord;
layout(location = 0) out vec4 FragColor;
layout(set = 0, binding = 2) uniform sampler2D Source;

vec3 RGBtoHSV(vec3 c)
{
    vec4 K = vec4(0.0, -1.0 / 3.0, 2.0 / 3.0, -1.0);
    vec4 p = c.g < c.b ? vec4(c.bg, K.wz) : vec4(c.gb, K.xy);
    vec4 q = c.r < p.x ? vec4(p.xyw, c.r) : vec4(c.r, p.yzx);

    float d = q.x - min(q.w, q.y);
    float e = 1.0e-10;
    return vec3(abs(q.z + (q.w - q.y) / (6.0 * d + e)), d / (q.x + e), q.x);
}

vec3 HSVtoRGB(vec3 c)
{
    vec4 K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
    vec3 p = abs(fract(c.xxx + K.xyz) * 6.0 - K.www);
    return c.z * mix(K.xxx, clamp(p - K.xxx, 0.0, 1.0), c.y);
}

void main()
{
   vec3 img = texture(Source, vTexCoord).rgb;
   img = RGBtoHSV(img);
   img.g = (distance(params.targetHue, img.r) > params.hueThresh) ? min(params.desat, img.g) : img.g;
   FragColor = vec4(HSVtoRGB(img), 1.0);
}

[BouncyBonBon]

this works great, thanks! the only issue i can find is that opposite ends of the target hue don't wrap around to eachother, so if you select red at 0 anything at 0.995 doesn't count even though its closer to the target hue than 0.01, which does count (same true for the other way so selecting 1 causes 0.005 to not count even though its closer than 0.99 which does count)

im too stupid to figure out how to program that lol. this works for what i needed though, thanks so much!

[hizzlekizzle]

Yes, I noticed that, as well. I didn't attempt to fix it at first, but I decided to give it a shot and it really made a big difference. I also switched from a threshold, which leads to harsh, ugly transitions, to a mix function which isn't as precise, but the transitions are smoother.

I set the default parameters to make the blood pop on Resident Evil 2:

#version 450

layout(push_constant) uniform Push
{
	vec4 SourceSize;
	vec4 OriginalSize;
	vec4 OutputSize;
	uint FrameCount;
	float targetHue, hueThresh, desat;
} params;

#pragma parameter targetHue "Target Hue" 0.99 0.0 1.0 0.005
#pragma parameter hueThresh "Hue Difference Sensitivity" 10.0 1.0 10.0 0.1
#pragma parameter desat "Minimum Saturation" 0.0 0.0 1.0 0.01

layout(std140, set = 0, binding = 0) uniform UBO
{
	mat4 MVP;
} global;

#pragma stage vertex
layout(location = 0) in vec4 Position;
layout(location = 1) in vec2 TexCoord;
layout(location = 0) out vec2 vTexCoord;

void main()
{
   gl_Position = global.MVP * Position;
   vTexCoord = TexCoord;
}

#pragma stage fragment
layout(location = 0) in vec2 vTexCoord;
layout(location = 0) out vec4 FragColor;
layout(set = 0, binding = 2) uniform sampler2D Source;

vec3 RGBtoHSV(vec3 c)
{
    vec4 K = vec4(0.0, -1.0 / 3.0, 2.0 / 3.0, -1.0);
    vec4 p = c.g < c.b ? vec4(c.bg, K.wz) : vec4(c.gb, K.xy);
    vec4 q = c.r < p.x ? vec4(p.xyw, c.r) : vec4(c.r, p.yzx);

    float d = q.x - min(q.w, q.y);
    float e = 1.0e-10;
    return vec3(abs(q.z + (q.w - q.y) / (6.0 * d + e)), d / (q.x + e), q.x);
}

vec3 HSVtoRGB(vec3 c)
{
    vec4 K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
    vec3 p = abs(fract(c.xxx + K.xyz) * 6.0 - K.www);
    return c.z * mix(K.xxx, clamp(p - K.xxx, 0.0, 1.0), c.y);
}

float wrappedDistance(float p1, float p2) {
    float d = abs(p1 - p2);
    d = mod(d + 0.5, 1.0) - 0.5;
    return length(d);
}

void main()
{
   vec3 img = texture(Source, vTexCoord).rgb;
   img = RGBtoHSV(img);
   float desaturated = min(params.desat, img.g);
   float hueDist = wrappedDistance(params.targetHue, img.r);
   img.g = mix(img.g, desaturated, clamp(hueDist * params.hueThresh, 0., 1.));
   FragColor = vec4(HSVtoRGB(img), 1.0);
}