[[ DefaultHandlers ]] Add lines in handler list for default handler addition in SE

This patch uses the docs library to fetch all the per-object-type messages
to populate the handler list. When choosing a new default handler to add form the
list, the handler is added to the script editor field.

Author: livecodeali

Toolset/libraries/revidedocumentationlibrary.livecodescript

@@ -190,6 +190,17 @@ function ideDocsFetchLCSElementOfType pEntryName, pType, pElement
    return ideDocsFetchElementOfType(pEntryName, "LiveCode Script", pType, pElement)
 end ideDocsFetchLCSElementOfType
 
+/* 
+Fetch all docs element of the given type in the LiveCode script dictionary.
+
+Returns:
+A numerically keyed array of data, each element of which is an array of data
+pertaining to a LiveCode script dictionary entry with the given type.
+*/
+function ideDocsFetchLCSElementsOfType pType
+   return __ideDocsFetchData("", "LiveCode Script", pType)
+end ideDocsFetchLCSElementsOfType
+
 /* 
 Fetch the data for LiveCode builder dictionary entries with name <pEntryName>
 
@@ -228,6 +239,17 @@ function ideDocsFetchLCBElementOfType pEntryName, pType, pElement
    return ideDocsFetchElementOfType(pEntryName, "LiveCode Builder", pType, pElement)
 end ideDocsFetchLCBElementOfType
 
+/* 
+Fetch all docs element of the given type in the LiveCode builder dictionary.
+
+Returns:
+A numerically keyed array of data, each element of which is an array of data
+pertaining to a LiveCode builder dictionary entry with the given type.
+*/
+function ideDocsFetchLCBElementsOfType pType
+   return __ideDocsFetchData("", "LiveCode Builder", pType)
+end ideDocsFetchLCBElementsOfType
+
 /* 
 Fetch the data for entries in the API for extension <pID> with name <pEntryName>
 
@@ -272,6 +294,19 @@ function ideDocsFetchExtensionElementOfType pID, pEntryName, pType, pElement
    return ideDocsFetchElementOfType(pEntryName, tLibraryName, pType, pElement)
 end ideDocsFetchExtensionElementOfType
 
+/* 
+Fetch all docs element of the given type in the LiveCode script dictionary.
+
+Returns:
+A numerically keyed array of data, each element of which is an array of data
+pertaining to a LiveCode script dictionary entry with the given type.
+*/
+function ideDocsFetchExtensionElementsOfType pID, pType
+   local tLibraryName
+   put revIDEExtensionProperty(pID, "title") into tLibraryName
+   return __ideDocsFetchData("", tLibraryName, pType)
+end ideDocsFetchExtensionElementsOfType
+
 /*
 Returns a list of library names, one per line, which have API entries in the dictionary.
 */

Toolset/palettes/script editor/behaviors/revseeditorbehavior.livecodescript

@@ -340,61 +340,16 @@ command loadScript
          # OK-2008-07-07 : Bug 6746
          seUpdateCheckSum sObjectId, tScript
       else
-         # AL-2015-09-21: Tweaked logic for default script
-         local tType, tStyle
-         put word 1 of the name of sObjectID into tType
-         if tType is among the items of "button,field,stack,graphic,scrollbar" then
-            put the style of sObjectId into tStyle
-         else if tType is "widget" then
-            put the kind of sObjectID into tStyle
-         else -- groups, cards, images and players have no style property so just pass empty
-            put empty into tStyle
-         end if
-         
-         local tDefaultScript
-         put seDefaultScript(tType, tStyle) into tDefaultScript
-         textSetScriptRaw tDefaultScript
-         
-         local tDefaultSelection
-         put seDefaultScriptSelection(tType, tStyle) into tDefaultSelection
-         
-         # OK-2008-08-19 : When a default script is put into an object, the object should be marked as modified
-         # in the script editor, as the script in the field is not the same as the object's actual script.
-         if tDefaultScript is not empty then
-            seSetObjectState sObjectId, "edited"
-         end if
-         
-         # OK-2008-07-07 : Bug 6746 - When a default script was loaded, it means the object's actual script was empty,
-         # therefore the checksum should represent this. 
-         local tEmpty
-         put empty into tEmpty
-         seUpdateChecksum sObjectId, tEmpty
-         
-         if tDefaultSelection is not empty then
-            # Try is needed here to allow the IDE to add objects to a script editor before opening it
-            try
-               select char (item 1 of tDefaultSelection) to (item 2 of tDefaultSelection) of field "Script" of me
-               
-               # OK-2009-01-17 : Bug 7601 - When a script is first loaded, slastSelectedChunk may be empty
-               # or incorrect as the user has not yet done a selection to trigger selectedChanged and update it.
-               put tDefaultSelection into sLastSelectedChunk
-            end try
-         else
-            select before field "Script" of me
-         end if
+         select before field "Script" of me
       end if
    end if
 
-   # Only load the previous context if we didn't use the default script and default selection,
-   # otherwise these will get overriden and the selection will be wrong.
-   if tDefaultSelection is empty then
-      # The lock messages is required, because otherwise an exitField is received before the contextLoad
-      # can execute, causing the context to be overwritten just before we load it. Not currently sure why 
-      # this happens...
-      lock messages
-      contextLoad
-      unlock messages
-   end if
+   # The lock messages is required, because otherwise an exitField is received before the contextLoad
+   # can execute, causing the context to be overwritten just before we load it. Not currently sure why 
+   # this happens...
+   lock messages
+   contextLoad
+   unlock messages
 
    # As we have changed the selection, update the rest of the script editor to reflect this
    --selectionUpdateRequest

Toolset/palettes/script editor/behaviors/revsehandlerlistbehavior.livecodescript

@@ -31,6 +31,11 @@ command initializeWithoutGrabbingFocus
 end initializeWithoutGrabbingFocus
 
 command updateSelectedHandler
+   if the cSelectedHandler of me is empty then
+      set the hilitedLines of field "Handlers" of me to empty
+      exit updateSelectedHandler
+   end if
+   
    local tLineNumber
    put 1 into tLineNumber
 
@@ -133,6 +138,22 @@ command update
    call "revSEGetHandlerList" to the cCaller of me
    put the result into tHandlers
 
+   local tDefaultHandlers, tIndex
+   put revSEDefaultHandlers() into tDefaultHandlers
+   set the wholematches to false
+   
+   local tCanAdd
+   repeat for each line tLine in tDefaultHandlers
+      if lineOffset(tLine, tHandlers) is not 0 then
+         next repeat
+      end if
+      if tCanAdd is empty then
+         put tLine into tCanAdd
+      else
+         put return & tLine after tCanAdd
+      end if
+   end repeat
+   
    filterHandlerNames tHandlers
 
    if sePrefGet("editor,sortHandlerList") is "alphabetical" then
@@ -148,12 +169,22 @@ command update
       sort tHandlers by handlerTypeSortCallback(word 1 of each) & word 2 of each
    end if
 
+   if tHandlers is not empty then
+      put return &return after tHandlers
+   end if
+   put tCanAdd after tHandlers
+   
    # Populate the handlers field with the formatted list of handlers
    local tText, tIcon
    repeat for each line tHandler in tHandlers
-      local tParseHandler
+      local tParseHandler, tHandlerExists
+      put true into tHandlerExists
       put word 1 to 2 of tHandler into tParseHandler
 
+      if the number of words in tHandler is 1 then
+         put false into tHandlerExists
+      end if
+      
       put "<p>" after tText
 
       local tIsPrivate
@@ -162,12 +193,19 @@ command update
          put true into tIsPrivate
          delete char 1 of tParseHandler
       end if
-
-      put getIcon(char 1 of tParseHandler, tIsPrivate) into tIcon
+      
+      if tHandlerExists then
+         put getIcon(char 1 of tParseHandler, tIsPrivate) into tIcon
+         if tIcon is not empty then
+            delete char 1 of tParseHandler
+         end if
+      else
+         put the id of image "icon-add.png" of stack "revIcons" into tIcon
+      end if
+      
       if tIcon is not empty then
          put merge("<sup shift=2><img src=[[tICon]]></img></sup>") after tText
       end if
-      delete char 1 of tParseHandler
 
       put tParseHandler & "</p>" after tText
    end repeat
@@ -221,23 +259,40 @@ command resize
    unlock screen
 end resize
 
-command closeAccept
-   lock screen
-   local tHandler
-   put line (the hilitedLine of field "Handlers" of me) of the cHandlers of field "Handlers" of me into tHandler
-   
+command jumpToHandler pHandler
    local tLineNumber
-   put word 3 of tHandler into tLineNumber
+   put word 3 of pHandler into tLineNumber
 
    # OK-2009-03-03: Bug 7450 - Also return the handler type, this will allow us to detect 
    # if the handler line number is wrong (due to uncompiling script). 
-   set the cChoice of me to tLineNumber & comma & word 2 of tHandler & comma & word 1 of tHandler
+   set the cChoice of me to tLineNumber & comma & word 2 of pHandler & comma & word 1 of pHandler
 
    if the cCallback of me is not empty then
       send the cCallback of me to the cCallbackTarget of me
    end if
 
    hideGroup
+end jumpToHandler
+
+command closeAccept
+   lock screen
+   local tHandler
+   put line (the hilitedLine of field "Handlers" of me) of the cHandlers of field "Handlers" of me into tHandler
+   
+   if the number of words in tHandler is 1 then
+      -- Adding a default handler
+      revSEAddDefaultHandler tHandler
+      update
+      set the wholematches to false
+      local tLine
+      put lineOffset(tHandler, the cHandlers of field "Handlers" of me) into tLine
+      select line tLine of field "Handlers" of me
+      put line tLine of the cHandlers of field "Handlers" of me into tHandler
+   end if
+   
+   -- Select the (now) extant handler
+   jumpToHandler tHandler
+   
    unlock screen
 end closeAccept
 

Toolset/palettes/script editor/behaviors/revsestackbehavior.livecodescript

@@ -2931,6 +2931,106 @@ on revSESetScript pScript
    dispatch "textSetScript" to field "Script" of me with pScript
 end revSESetScript
 
+function revSEGetScript pScript
+   dispatch function "textGetScript" to field "Script" of me
+   return the result
+end revSEGetScript
+
 on revSEIndentScript
    dispatch "scriptFormat" to field "Script" of me with "script"
 end revSEIndentScript
+
+private command appendToList @xList, pValue
+   if xList is not empty then
+      put return & pValue after xList
+   else
+      put pValue into xList
+   end if
+end appendToList
+
+local sHandlersA
+private function revSEDefaultHandlerInfoForObjectType pObjType
+   if sHandlersA[pObjType] is not empty then
+      return sHandlersA[pObjType]
+   end if
+   
+   local tMessages
+   put ideDocsFetchLCSElementsOfType("message") into tMessages
+
+   local tMessageList
+   repeat for each element tElement in tMessages
+      local tAssociations
+      put tElement["Associations"] into tAssociations
+      filter elements of tAssociations with pObjType
+      if tAssociations is not empty then
+         appendToList tMessageList, tElement["display name"]
+      end if
+   end repeat
+   sort tMessageList
+   put tMessageList into sHandlersA[pObjType]
+   return tMessageList
+end revSEDefaultHandlerInfoForObjectType
+
+private function revSEDefaultHandlerInfoForWidget pWidgetKind
+   if sHandlersA[pWidgetKind] is not empty then
+      return sHandlersA[pWidgetKind]
+   end if
+   local tMessages
+   put ideDocsFetchExtensionElementsOfType(pWidgetKind, "message") into tMessages
+   
+   local tMessageList
+   repeat for each element tElement in tMessages
+      appendToList tMessageList, tElement["display name"]
+   end repeat
+   sort tMessageList
+   put tMessageList into sHandlersA[pWidgetKind]
+   return tMessageList
+end revSEDefaultHandlerInfoForWidget
+
+function revSEDefaultHandlers
+   local tObject
+   revSEGetCurrentObject
+   put the result into tObject
+   if tObject is empty then
+      return empty
+   end if
+   return revSEDefaultHandlersForObject(tObject)
+end revSEDefaultHandlers
+
+function revSEDefaultHandlersForObject pObj
+   local tType
+   put word 1 of the name of pObj into tType
+   if tType is "widget" then
+      local tKind
+      put the kind of pObj into tKind
+      return revSEDefaultHandlerInfoForWidget(tKind)
+   end if
+   
+   return revSEDefaultHandlerInfoForObjectType(tType)
+end revSEDefaultHandlersForObject
+
+private function revSEDefaultScriptOfHandler pHandler
+   // At the moment, don't try to find default scripts anywhere
+   local tDefaultHandler
+   put "on" && pHandler & return into tDefaultHandler
+   put return after tDefaultHandler
+   put "end" && pHandler after tDefaultHandler
+   
+   return tDefaultHandler
+end revSEDefaultScriptOfHandler
+
+command revSEAddDefaultHandler pHandler
+   local tDefaultScript
+   put revSEDefaultScriptOfHandler(pHandler) into tDefaultScript
+   
+   local tNewScript
+   put revSEGetScript() into tNewScript
+   if tNewScript is not empty then
+      if the last line of tNewScript is not empty then
+         put return after tNewScript
+      end if
+      put return after tNewScript
+   end if
+   put tDefaultScript after tNewScript
+   revSESetScript(tNewScript)
+end revSEAddDefaultHandler