ProjectTSB · k22992068-crypto · Jun 8, 2026 · Jun 10, 2026 · Jun 13, 2026 · Jun 13, 2026
diff --git a/Asset/data/asset/functions/artifact/1492.your_thoughts_frames/give/1.trigger.mcfunction b/Asset/data/asset/functions/artifact/1492.your_thoughts_frames/give/1.trigger.mcfunction
@@ -0,0 +1,7 @@
+#> asset:artifact/1492.your_thoughts_frames/give/1.trigger
+#
+# 神器の取得処理の呼び出し時に実行されるfunction
+#
+# @within tag/function asset:artifact/give
+
+execute if data storage asset:context {id:1492} run function asset:artifact/1492.your_thoughts_frames/give/2.give
diff --git a/Asset/data/asset/functions/artifact/1492.your_thoughts_frames/give/2.give.mcfunction b/Asset/data/asset/functions/artifact/1492.your_thoughts_frames/give/2.give.mcfunction
@@ -0,0 +1,68 @@
+#> asset:artifact/1492.your_thoughts_frames/give/2.give
+#
+# 神器の作成部 ここでID等を定義する
+#
+# @user
+# @within function asset:artifact/1492.your_thoughts_frames/give/1.trigger
+
+# 神器の説明や消費MPなどをここで設定する。
+# 最後にasset:artifact/common/giveを実行することで入手可能。
+
+# 神器のID (int) スプレッドシートの値を入れる
+    data modify storage asset:artifact ID set value 1492
+# 神器のベースアイテム
+    data modify storage asset:artifact Item set value "minecraft:stick"
+# 神器の名前 (TextComponentString)
+    data modify storage asset:artifact Name set value '[{"text":"『故","color":"#DAA1FF"},{"text":"想","color":"#DAA1FF"},{"text":"の","color":"#C5A5FF"},{"text":"額","color":"#B8A8FF"},{"text":"縁』","color":"#9EAEFF"}]'
+# 神器の説明文 (TextComponentString[])
+    data modify storage asset:artifact Lore set value ['{"text":"発動時、敵が”気持ちの欠片”を近くに落とす"}','{"text":"気持ちの欠片に触れたプレイヤーはMP回復量+25%を得る"}','{"text":"バフは2秒ごとに効果量が-5%され、10秒後に切れる"}','{"text":"「まだ喉元に噛みつく牙はある？」","color":"gray"}']
+# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
+    # data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.stick"}'
+    # data modify storage asset:artifact ConsumeItem.Count set value 1
+    # data modify storage asset:artifact ConsumeItem.Extra set value 
+# 使用回数 (int) (オプション)
+    # data modify storage asset:artifact RemainingCount set value 
+# 神器を発動できるスロット (string) Wikiを参照
+    data modify storage asset:artifact Slot set value "offhand"
+# 神器のトリガー (string) Wikiを参照
+    data modify storage asset:artifact Trigger set value "onAttack"
+# 神器の発動条件 (TextComponentString) (オプション)
+    data modify storage asset:artifact Condition set value '{"text":"3.1416%の確率で発動"}'
+# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.Damage set value [0,0]
+# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.AttackType set value [Physical,Magic]
+# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.ElementType set value [Fire,Water,Thunder,None]
+# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.BypassResist set value 
+# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.IsRangeAttack set value 
+# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.AttackRange set value 
+# MP消費量 (int) 
+    data modify storage asset:artifact MPCost set value 0
+# MP必要量 (int) (オプション)
+    # data modify storage asset:artifact MPRequire set value 
+# MP回復量 (int) 
+    # data modify storage asset:artifact MPHealWhenHit set value 
+# 神器のクールダウン 
+    data modify storage asset:artifact LocalCooldown set value 60
+# 種別クールダウン ({Type: string, Duration: int}) (オプション)
+    # data modify storage asset:artifact TypeCooldown.Type set value 
+    # data modify storage asset:artifact TypeCooldown.Duration set value
+# グローバルクールダウン (int) (オプション)
+    # data modify storage asset:artifact SpecialCooldown set value 
+# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    data modify storage asset:artifact DisableCooldownMessage set value true
+# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableMPMessage set value 
+# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
+    # data modify storage asset:artifact DisableBreakSound set value
+# 扱える神 (string[]) Wikiを参照
+    data modify storage asset:artifact CanUsedGod set value "ALL"
+# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
+    # data modify storage asset:artifact CustomNBT set value {}
+
+# 神器の入手用function
+    function asset:artifact/common/give
diff --git a/Asset/data/asset/functions/artifact/1492.your_thoughts_frames/trigger/1.trigger.mcfunction b/Asset/data/asset/functions/artifact/1492.your_thoughts_frames/trigger/1.trigger.mcfunction
@@ -0,0 +1,8 @@
+#> asset:artifact/1492.your_thoughts_frames/trigger/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idのoffhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{offhand:1492} run function asset:artifact/1492.your_thoughts_frames/trigger/2.check_condition
diff --git a/...a/asset/functions/artifact/1492.your_thoughts_frames/trigger/2.check_condition.mcfunction b/...a/asset/functions/artifact/1492.your_thoughts_frames/trigger/2.check_condition.mcfunction
@@ -0,0 +1,19 @@
+#> asset:artifact/1492.your_thoughts_frames/trigger/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/1492.your_thoughts_frames/trigger/1.trigger
+
+# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
+    function asset:artifact/common/check_condition/offhand
+
+# IsDoT:trueならCanUsedを削除
+    execute if entity @s[tag=CanUsed] if data storage asset:context Attack{IsDoT:true} run tag @s remove CanUsed
+
+# 3.1416%の確率でCanUsedを残す(7%*51%*88%=3.1416%)
+    execute unless predicate lib:random_pass_per/7 run tag @s remove CanUsed
+    execute unless predicate lib:random_pass_per/51 run tag @s remove CanUsed
+    execute unless predicate lib:random_pass_per/88 run tag @s remove CanUsed
+
+# CanUsedタグをチェックして3.main.mcfunctionを実行する
+    execute if entity @s[tag=CanUsed] run function asset:artifact/1492.your_thoughts_frames/trigger/3.main
diff --git a/Asset/data/asset/functions/artifact/1492.your_thoughts_frames/trigger/3.main.mcfunction b/Asset/data/asset/functions/artifact/1492.your_thoughts_frames/trigger/3.main.mcfunction
@@ -0,0 +1,19 @@
+#> asset:artifact/1492.your_thoughts_frames/trigger/3.main
+#
+# 神器のメイン処理部
+#
+# @within function asset:artifact/1492.your_thoughts_frames/trigger/2.check_condition
+
+# 性能として、水属性のビルドで手数があるビルドか、上振れたときだとかなりMPの回復の足しになるくらいがうれしい
+
+# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
+    function asset:artifact/common/use/offhand
+
+# 攻撃対象の近くにオーブを召喚
+    execute at @e[type=#lib:living,type=!player,tag=Victim,distance=..30,limit=1] run function asset:artifact/1492.your_thoughts_frames/trigger/summon
+
+# 演出
+    playsound block.amethyst_block.chime player @a ~ ~ ~ 5 0.8
+    playsound minecraft:block.enchantment_table.use player @a ~ ~ ~ 0.9 1.4 0.0
+    playsound minecraft:block.amethyst_cluster.hit player @a ~ ~ ~ 5.0 1.35 0.0
+    playsound minecraft:block.amethyst_block.break player @a ~ ~ ~ 10 2 0.0
diff --git a/Asset/data/asset/functions/artifact/1492.your_thoughts_frames/trigger/summon.mcfunction b/Asset/data/asset/functions/artifact/1492.your_thoughts_frames/trigger/summon.mcfunction
@@ -0,0 +1,16 @@
+#> asset:artifact/1492.your_thoughts_frames/trigger/summon
+#
+# オーブの召喚
+#
+# @within function asset:artifact/1492.your_thoughts_frames/trigger/3.main
+
+# 演出
+    particle item pink_stained_glass ~ ~1 ~ 0.3 0.5 0.3 0.1 100 normal @a
+
+# 召喚
+    data modify storage api: Argument.ID set value 1164
+    data modify storage api: Argument.FieldOverride.Stack set value 5
+    data modify storage api: Argument.FieldOverride.Amount set value 0.05d
+    data modify storage api: Argument.FieldOverride.Duration set value 200
+    data modify storage api: Argument.FieldOverride.DecreaInterval set value 40
+    execute positioned ~ ~1 ~ run function api:object/summon
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/_/end.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/_/end.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0373.longevity_your_thoughts/_/end
+#
+# Effectの効果の終了時に実行されるfunction
+#
+# @within tag/function asset:effect/end
+
+execute if data storage asset:context {id:373} run function asset:effect/0373.longevity_your_thoughts/end/
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/_/given.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/_/given.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0373.longevity_your_thoughts/_/given
+#
+# Effectが付与された時に実行されるfunction
+#
+# @within tag/function asset:effect/given
+
+execute if data storage asset:context {id:373} run function asset:effect/0373.longevity_your_thoughts/given/
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/_/re-given.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/_/re-given.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0373.longevity_your_thoughts/_/re-given
+#
+# Effectが上書きされた時に実行されるfunction
+#
+# @within tag/function asset:effect/re-given
+
+execute if data storage asset:context {id:373} run function asset:effect/0373.longevity_your_thoughts/re-given/
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/_/register.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/_/register.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0373.longevity_your_thoughts/_/register
+#
+#
+#
+# @within tag/function asset:effect/register
+
+execute if data storage asset:context {id:373} run function asset:effect/0373.longevity_your_thoughts/register
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/_/tick.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/_/tick.mcfunction
@@ -0,0 +1,7 @@
+#> asset:effect/0373.longevity_your_thoughts/_/tick
+#
+# Effectが発動している間毎tick実行されるfunction
+#
+# @within tag/function asset:effect/tick
+
+execute if data storage asset:context {id:373} run function asset:effect/0373.longevity_your_thoughts/tick/
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/effect/reset.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/effect/reset.mcfunction
@@ -0,0 +1,12 @@
+#> asset:effect/0373.longevity_your_thoughts/effect/reset
+#
+# エフェクトのリセット処理
+#
+# @within function
+#   asset:effect/0373.longevity_your_thoughts/end/
+#   asset:effect/0373.longevity_your_thoughts/re-given/
+#   asset:effect/0373.longevity_your_thoughts/tick/update_effect
+
+# 補正をリセット
+    data modify storage api: Argument.UUID set from storage asset:context this.UUID
+    function api:modifier/mp_heal/remove
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/effect/set.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/effect/set.mcfunction
@@ -0,0 +1,28 @@
+#> asset:effect/0373.longevity_your_thoughts/effect/set
+#
+# 初期化処理
+#
+# @within function
+#   asset:effect/0373.longevity_your_thoughts/given/
+#   asset:effect/0373.longevity_your_thoughts/re-given/
+#   asset:effect/0373.longevity_your_thoughts/tick/update_effect
+
+#> val
+# @private
+    #declare score_holder $15G.Stack
+    #declare score_holder $15G.Amount
+
+# MP回復量バフの計算（Stack*Amount）
+    execute store result score $15G.Stack Temporary run data get storage asset:context Stack 1
+    execute store result score $15G.Amount Temporary run data get storage asset:context this.Amount 100
+    scoreboard players operation $15G.Amount Temporary *= $15G.Stack Temporary
+
+# MP回復量
+    data modify storage api: Argument.UUID set from storage asset:context this.UUID
+    execute store result storage api: Argument.Amount double 0.01 run scoreboard players get $15G.Amount Temporary
+    data modify storage api: Argument.Operation set value "multiply"
+    function api:modifier/mp_heal/add
+
+# リセット
+    scoreboard players reset $15G.Stack Temporary
+    scoreboard players reset $15G.Amount Temporary
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/end/.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/end/.mcfunction
@@ -0,0 +1,8 @@
+#> asset:effect/0373.longevity_your_thoughts/end/
+#
+# Effectの効果が切れた時の処理
+#
+# @within function asset:effect/0373.longevity_your_thoughts/_/end
+
+# 補正をリセット
+    function asset:effect/0373.longevity_your_thoughts/effect/reset
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/given/.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/given/.mcfunction
@@ -0,0 +1,10 @@
+#> asset:effect/0373.longevity_your_thoughts/given/
+#
+# Effectが付与された時の処理
+#
+# @within function asset:effect/0373.longevity_your_thoughts/_/given
+
+# 初期化処理
+    function asset:effect/0373.longevity_your_thoughts/effect/set
+# TickにDecreaIntervalをセット
+    data modify storage asset:context this.Tick set from storage asset:context this.DecreaInterval
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/re-given/.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/re-given/.mcfunction
@@ -0,0 +1,10 @@
+#> asset:effect/0373.longevity_your_thoughts/re-given/
+#
+# Effectが上書きされた時の処理
+#
+# @within function asset:effect/0373.longevity_your_thoughts/_/re-given
+
+# 補正をリセット
+    function asset:effect/0373.longevity_your_thoughts/effect/reset
+# 初期化処理
+    function asset:effect/0373.longevity_your_thoughts/effect/set
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/register.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/register.mcfunction
@@ -0,0 +1,42 @@
+#> asset:effect/0373.longevity_your_thoughts/register
+#
+# Effectのデータを指定
+#
+# @within function asset:effect/0373.longevity_your_thoughts/_/register
+
+# ExtendsSafe (boolean) (default = false)
+    # data modify storage asset:effect ExtendsSafe set value true
+# ID (int)
+    data modify storage asset:effect ID set value 373
+# 名前 (TextComponentString)
+    data modify storage asset:effect Name set value '{"text":"遺るあなたの想い","color":"#DAA1FF"}'
+# 説明文 (TextComponentString[])
+    data modify storage asset:effect Description set value ['{"text":"MP回復量が上昇する"}','{"text":"効果は時間とともに減少する"}']
+# 効果時間 (int) (default = API || error)
+    # data modify storage asset:effect Duration set value 
+# スタック (int) (default = API || 1)
+    # data modify storage asset:effect Stack set value 
+# 効果時間の操作方法 (default = API || "replace")
+    data modify storage asset:effect DurationOperation set value "forceReplace"
+# スタックの操作方法 (default = API || "replace")
+    data modify storage asset:effect StackOperation set value "forceReplace"
+# 最大効果時間 (int) (default = 2147483647)
+    # data modify storage asset:effect MaxDuration set value 
+# 最大スタック (int) (default = 2147483647)
+    # data modify storage asset:effect MaxStack set value 
+# 悪い効果か否か (boolean)
+    data modify storage asset:effect IsBadEffect set value false
+# 死亡時のエフェクトの処理 (default = "remove")
+    # data modify storage asset:effect ProcessOnDied set value 
+# 消すのに必要なレベル (int) (default = 1)
+    data modify storage asset:effect RequireClearLv set value 3
+# エフェクトをUIに表示するか (boolean) (default = true)
+    # data modify storage asset:effect Visible set value 
+# エフェクトのスタックををUIに表示するか (boolean) (default = true)
+    # data modify storage asset:effect StackVisible set value
+
+# フィールド
+    data modify storage asset:effect Field.UUID set value [I;1,3,373,0]
+    data modify storage asset:effect Field.Amount set value 0.05d
+    data modify storage asset:effect Field.DecreaInterval set value 40
+    data modify storage asset:effect Field.Tick set value 40
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/tick/.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/tick/.mcfunction
@@ -0,0 +1,9 @@
+#> asset:effect/0373.longevity_your_thoughts/tick/
+#
+# Effectのtick処理
+#
+# @within function asset:effect/0373.longevity_your_thoughts/_/tick
+
+# DecreaIntervalTickごとにスタックを減らし効果を更新する
+    execute store result storage asset:context this.Tick int 0.9999999999 run data get storage asset:context this.Tick 1
+    execute if data storage asset:context this{Tick:0} run function asset:effect/0373.longevity_your_thoughts/tick/set_modifier
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/tick/set_modifier.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/tick/set_modifier.mcfunction
@@ -0,0 +1,12 @@
+#> asset:effect/0373.longevity_your_thoughts/tick/set_modifier
+#
+# 効果の更新
+#
+# @within function asset:effect/0373.longevity_your_thoughts/tick/
+
+# TickにDecreaIntervalをセット
+    data modify storage asset:context this.Tick set from storage asset:context this.DecreaInterval
+
+# スタックを減らし効果量を更新
+    # もしスタックが1より多いならスタックを減らし、効果を更新する
+    execute unless data storage asset:context this{Stack:..1} run function asset:effect/0373.longevity_your_thoughts/tick/update_effect
diff --git a/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/tick/update_effect.mcfunction b/Asset/data/asset/functions/effect/0373.longevity_your_thoughts/tick/update_effect.mcfunction
@@ -0,0 +1,12 @@
+#> asset:effect/0373.longevity_your_thoughts/tick/update_effect
+#
+# エフェクトの終了
+#
+# @within function asset:effect/0373.longevity_your_thoughts/tick/set_modifier
+
+# スタックと効果量の更新
+    execute store result storage asset:context Stack int 0.9999999999 run data get storage asset:context Stack
+    # 補正をリセット
+    function asset:effect/0373.longevity_your_thoughts/effect/reset
+    # 効果量の更新
+    execute unless data storage asset:context this{Stack:0} run function asset:effect/0373.longevity_your_thoughts/effect/set
diff --git a/Asset/data/asset/functions/object/1164.piece_of_creation/init/.mcfunction b/Asset/data/asset/functions/object/1164.piece_of_creation/init/.mcfunction
@@ -0,0 +1,12 @@
+#> asset:object/1164.piece_of_creation/init/
+#
+# Objectのinit時の処理
+#
+# @within asset:object/alias/1164/init
+
+# 召喚場所からランダムに少し拡散する
+    data modify storage lib: Argument.Bounds set value [[2d,2d],[0d,0d],[2d,2d]]
+    function lib:spread_entity/
+
+# sound
+    playsound minecraft:entity.vex.charge player @a ~ ~ ~ 5.0 1.75 0.0
diff --git a/Asset/data/asset/functions/object/1164.piece_of_creation/register.mcfunction b/Asset/data/asset/functions/object/1164.piece_of_creation/register.mcfunction
@@ -0,0 +1,23 @@
+#> asset:object/1164.piece_of_creation/register
+#
+# Objectのデータを指定
+#
+# @within function asset:object/alias/1164/register
+
+# 継承(オプション)
+    # data modify storage asset:object Extends append value 
+    # function asset:object/extends
+# 他のObjectに継承されることを許可するか (boolean) (オプション)
+    # data modify storage asset:object ExtendsSafe set value 
+# 継承されることを前提とした、抽象的なObjectであるかどうか(boolean)
+    data modify storage asset:object IsAbstract set value false
+# Tickするかどうか(boolean) (オプション)
+    # data modify storage asset:object IsTicking set value 
+
+# ID (int)
+    data modify storage asset:object ID set value 1164
+# フィールド(オプション)
+    data modify storage asset:object Field.Stack set value 5
+    data modify storage asset:object Field.Amount set value 0.05
+    data modify storage asset:object Field.Duration set value 200
+    data modify storage asset:object Field.DecreaTime set value 40
diff --git a/Asset/data/asset/functions/object/1164.piece_of_creation/summon/.mcfunction b/Asset/data/asset/functions/object/1164.piece_of_creation/summon/.mcfunction
@@ -0,0 +1,11 @@
+#> asset:object/1164.piece_of_creation/summon/
+#
+# Object召喚処理の呼び出し時に実行されるfunction
+#
+# @within asset:object/alias/1164/summon
+
+# 元となるEntityを召喚する
+    execute as 0-0-0-0-0 in minecraft:overworld positioned as @s run tp @s ~ ~ ~ ~ 0
+    data modify storage asset:temp Args.Rotation set from entity 0-0-0-0-0 Rotation
+    function asset:object/1164.piece_of_creation/summon/m with storage asset:temp Args
+    data remove storage asset:temp Args
diff --git a/Asset/data/asset/functions/object/1164.piece_of_creation/summon/m.mcfunction b/Asset/data/asset/functions/object/1164.piece_of_creation/summon/m.mcfunction
@@ -0,0 +1,7 @@
+#> asset:object/1164.piece_of_creation/summon/m
+#
+# 
+#
+# @within function asset:object/1164.piece_of_creation/summon/
+
+$summon item_display ~ ~ ~ {Rotation:$(Rotation),teleport_duration:1,Tags:["ObjectInit","Uninterferable"],brightness:{sky:15,block:15},item:{id:"stick",Count:1b,tag:{CustomModelData:20620}},transformation:{left_rotation:[0f,0f,0f,1f],right_rotation:[0f,0f,0f,1f],translation:[0f,0f,0f],scale:[1.4f,1.4f,1.4f]}}