[[ DefaultHandlers ]] Improve default handler construction

This patch reinstates the use of default scripts specified by widgets
and allows them to have multiple handlers within them.

It also adds the ability to override default scripts for handlers
dependent on 'classic' object type, for example different default
scripts for a standard button and an option menu.

Finally, if a default script override is not present, info from the
documentation is used to construct a default handler with params.

Author: livecodeali

Toolset/libraries/revidelibrary.8.livecodescript

@@ -4135,6 +4135,9 @@ function revIDESpecialFolderPath pKey
       case "Object Property Definitions"
          return item 1 to -3 of the filename of stack "home" & "/Toolset/resources/supporting_files/property_definitions"
          break
+      case "Object Default Scripts"
+         return item 1 to -3 of the filename of stack "home" & "/Toolset/resources/supporting_files/default_scripts"
+         break
       case "Standalone Settings Definitions"
          return item 1 to -3 of the filename of stack "home" & "/Toolset/resources/supporting_files/standalone_settings"
          break
@@ -5496,6 +5499,52 @@ function revIDEDefaultExtensionIcon pType, pRetina
    end switch
 end revIDEDefaultExtensionIcon
 
+function revIDEDefaultScript pObject, pHandler
+   local tDefaultScript, tType
+   put ideObjectTypeFromObject(pObject) into tType
+   if word 1 of the name of pObject is "widget" then
+      put revIDEWidgetDefaultScript(tType) into tDefaultScript
+   else
+      put revIDEClassicObjectDefaultScript(tType) into tDefaultScript
+   end if
+   
+   lock screen
+   lock messages
+   create invisible stack "revDefaultScriptHolder"
+   try
+      set the script of it to tDefaultScript
+   catch tError
+   end try
+   local tHandlers
+   put the revAvailableHandlers of it into tHandlers
+   delete stack "revDefaultScriptHolder"
+   local tHandlerStart, tHandlerEnd, tHandlerInfo, tHandlerInfoLine
+   set the wholematches to false
+   -- Ensure we don't accidentally match a substring by putting
+   -- spaces around the handler name
+   put lineOffset(" " & pHandler & " ", tHandlers) into tHandlerInfoLine
+   put line tHandlerInfoLine of tHandlers into tHandlerInfo
+   -- We want to include any comments before the handler declaration
+   -- so find the previous handler 
+   put word 3 of tHandlerInfo into tHandlerStart
+   put word 4 of tHandlerInfo into tHandlerEnd
+   repeat while word 1 of line tHandlerStart of tDefaultScript is not empty
+      subtract 1 from tHandlerStart
+   end repeat
+   unlock messages
+   unlock screen
+   return line tHandlerStart to tHandlerEnd of tDefaultScript
+end revIDEDefaultScript
+
+function revIDEClassicObjectDefaultScript pType
+   local tFolder
+   put revIDESpecialFolderPath("Object Default Scripts") into tFolder
+   if there is a stack (tFolder & slash & pType & ".livecodescript") then
+      return the script of stack (tFolder & slash & pType & ".livecodescript")
+   end if
+   return empty
+end revIDEClassicObjectDefaultScript
+
 function revIDEWidgetDefaultScript pKind
    return revIDEExtensionProperty(pKind, "defaultScript")
 end revIDEWidgetDefaultScript

Toolset/palettes/script editor/behaviors/revsestackbehavior.livecodescript

@@ -2949,42 +2949,46 @@ private command appendToList @xList, pValue
 end appendToList
 
 local sHandlersA
+private function getHandlerList pObjType
+   get the keys of sHandlersA[pObjType]
+   sort it 
+   return it
+end getHandlerList
+
 private function revSEDefaultHandlerInfoForObjectType pObjType
    if sHandlersA[pObjType] is not empty then
-      return sHandlersA[pObjType]
+      return getHandlerList (pObjType)
    end if
 
    local tMessages
    put ideDocsFetchLCSElementsOfType("message") into tMessages
-
+   
    local tMessageList
    repeat for each element tElement in tMessages
       local tAssociations
       put tElement["Associations"] into tAssociations
       filter elements of tAssociations with pObjType
       if tAssociations is not empty then
-         appendToList tMessageList, tElement["display name"]
+         put tElement into tMessageList[tElement["display name"]]
       end if
    end repeat
-   sort tMessageList
    put tMessageList into sHandlersA[pObjType]
-   return tMessageList
+   return getHandlerList(pObjType)
 end revSEDefaultHandlerInfoForObjectType
 
 private function revSEDefaultHandlerInfoForWidget pWidgetKind
    if sHandlersA[pWidgetKind] is not empty then
-      return sHandlersA[pWidgetKind]
+      return getHandlerList(pWidgetKind)
    end if
    local tMessages
    put ideDocsFetchExtensionElementsOfType(pWidgetKind, "message") into tMessages
 
    local tMessageList
    repeat for each element tElement in tMessages
-      appendToList tMessageList, tElement["display name"]
+      put tElement into tMessageList[tElement["display name"]]
    end repeat
-   sort tMessageList
    put tMessageList into sHandlersA[pWidgetKind]
-   return tMessageList
+   return getHandlerList(pWidgetKind)
 end revSEDefaultHandlerInfoForWidget
 
 function revSEDefaultHandlers
@@ -3009,19 +3013,39 @@ function revSEDefaultHandlersForObject pObj
    return revSEDefaultHandlerInfoForObjectType(tType)
 end revSEDefaultHandlersForObject
 
-private function revSEDefaultScriptOfHandler pHandler
-   // At the moment, don't try to find default scripts anywhere
-   local tDefaultHandler
-   put "on" && pHandler & return into tDefaultHandler
-   put return after tDefaultHandler
-   put "end" && pHandler after tDefaultHandler
+function revSEConstructDefaultScript pObj, pHandler
+   local tType
+   put word 1 of the name of pObj into tType
+   if tType is "widget" then
+      put the kind of pObj into tType
+   end if
+   
+   local tInfo
+   put sHandlersA[tType][pHandler] into tInfo
 
-   return tDefaultHandler
-end revSEDefaultScriptOfHandler
+   local tScript
+   -- Don't include summary for now as it has some docs specific markup
+   --put "--" && tInfo["Summary"] & return into tScript
+   put "on" && pHandler after tScript
+   repeat with x = 1 to the number of elements in tInfo["params"]
+      if x is not 1 then
+         put "," after tScript
+      end if
+      put " " & tInfo["params"][x]["name"] after tScript
+   end repeat
+   put return & return & "end" && pHandler after tScript
+   return tScript
+end revSEConstructDefaultScript
 
 command revSEAddDefaultHandler pHandler
-   local tDefaultScript
-   put revSEDefaultScriptOfHandler(pHandler) into tDefaultScript
+   local tDefaultScript, tObject
+   revSEGetCurrentObject
+   put the result into tObject
+   put revIDEDefaultScript(tObject, pHandler) into tDefaultScript
+   
+   if tDefaultScript is empty then
+      put revSEConstructDefaultScript(tObject, pHandler) into tDefaultScript
+   end if
 
    local tNewScript
    put revSEGetScript() into tNewScript

Toolset/resources/supporting_files/default_scripts/com.livecode.interface.classic.Button.livecodescript

@@ -0,0 +1,6 @@
+script "com.livecode.interface.classic.Button"
+-- Sent when the mouse is released after clicking
+-- pMouseButton specifies which mouse button was pressed
+on mouseUp pMouseButton
+
+end mouseUp