feat(monorepo): [party_management] Incorporates party management into core services

.env

@@ -1,4 +1,3 @@
-SERVICE_NAME=hellgate
 OTP_VERSION=28.5.0
 REBAR_VERSION=3.26
 THRIFT_VERSION=0.14.2.3

.github/workflows/erlang-checks.yaml

@@ -0,0 +1,41 @@
+name: Erlang CI Checks
+
+on:
+  push:
+    branches:
+      - "master"
+      - "epic/**"
+  pull_request:
+    branches: ["**"]
+
+jobs:
+  setup:
+    name: Load .env
+    runs-on: ubuntu-latest
+    outputs:
+      otp-version: ${{ steps.otp-version.outputs.version }}
+      rebar-version: ${{ steps.rebar-version.outputs.version }}
+      thrift-version: ${{ steps.thrift-version.outputs.version }}
+    steps:
+      - name: Checkout repository
+        uses: actions/checkout@v4
+      - run: grep -v '^#' .env >> $GITHUB_ENV
+      - id: otp-version
+        run: echo "::set-output name=version::$OTP_VERSION"
+      - id: rebar-version
+        run: echo "::set-output name=version::$REBAR_VERSION"
+      - id: thrift-version
+        run: echo "::set-output name=version::$THRIFT_VERSION"
+
+  run:
+    name: Run checks
+    needs: setup
+    uses: valitydev/erlang-workflows/.github/workflows/erlang-parallel-build.yml@v1
+    with:
+      otp-version: ${{ needs.setup.outputs.otp-version }}
+      rebar-version: ${{ needs.setup.outputs.rebar-version }}
+      use-thrift: true
+      thrift-version: ${{ needs.setup.outputs.thrift-version }}
+      run-ct-with-compose: true
+      cache-version: v4
+      upload-coverage: false

Makefile

@@ -67,8 +67,8 @@ wdeps-%: dev-image
 # Database tasks
 
 ifeq (db,$(firstword $(MAKECMDGOALS)))
-  DATABASE_NAME := $(wordlist 2,$(words $(MAKECMDGOALS)),$(MAKECMDGOALS))
-  $(eval $(DATABASE_NAME):;@:)
+	DATABASE_NAME := $(wordlist 2,$(words $(MAKECMDGOALS)),$(MAKECMDGOALS))
+	$(eval $(DATABASE_NAME):;@:)
 endif
 
 db:

README.md

@@ -99,3 +99,25 @@ $ make wdeps-test
 ## Служебные лимиты
 
 Нужно уметь _ограничивать_ максимальное _ожидаемое_ количество тех или иных объектов, превышение которого может негативно влиять на качество обслуживания системы. Например, мы можем считать количество _выводов_ одним участником неограниченным, однако при этом неограниченное количество созданных _личностей_ мы совершенно не ожидаем. В этом случае возможно будет разумно ограничить их количество сверху труднодостижимой для подавляющего большинства планкой, например, в 1000 объектов. В идеале подобное должно быть точечно конфигурируемым.
+
+# Party Management
+
+Managing parties involved in payment processing.
+
+## Building
+
+We widelly use Thrift to define RPC protocols.
+So it needs to have [our Thrift compiler](https://github.com/rbkmoney/thrift) in PATH to build this service.
+The recommended way to achieve this is by using our [build image](https://github.com/rbkmoney/image-build-erlang).
+
+# Party management client
+
+Клиент для сервиса PartyManagement. Спецификацию сервиса можно найти в rbkmoney/damsel в proto/payment_processing.thrift.
+
+## API
+
+Низкоуровневый thrift интерфес предоставляется модулем `party_client_thrift`. Его функции принимают и возвращают thrift объекты.
+
+Более erlang-like интерфес будет предоставляться модулем `party_client`. Его функции должны принимать и возвращать не thrift объекты, а обычные map, абстрагируя пользователей библиотеки от транспортного протокола. На данный момент этот интерфейс не реализован.
+
+Большая часть функций библиотеки ожидает в аргументах получить клиент и текущий контекст. Клиент представляет собой объект, с параметрами для запуска служебных процессов и обращения к ним, ожидается что он будет создан единожды. Контекст описывает текущее окружение, хранит информацию о пользователе, woody context и т.д.

apps/party_client/src/party_client.app.src

@@ -0,0 +1,18 @@
+{application, party_client, [
+    {description, "PartyManagement client"},
+    {vsn, "1.0.0"},
+    {registered, []},
+    {applications, [
+        kernel,
+        stdlib,
+        genlib,
+        damsel,
+        prometheus,
+        woody
+    ]},
+    {env, [
+        {services, #{
+            party_management => "http://party-management:8022/v1/processing/partymgmt"
+        }}
+    ]}
+]}.

apps/party_client/src/party_client.erl

@@ -0,0 +1,47 @@
+-module(party_client).
+
+-export([create_client/0]).
+-export([create_client/1]).
+-export([create_context/0]).
+-export([create_context/1]).
+-export([child_spec/2]).
+-export([start_link/1]).
+
+%% Client types
+
+-type context() :: party_client_thrift:context().
+-type context_options() :: party_client_context:options().
+
+-type client() :: party_client_thrift:client().
+-type client_options() :: party_client_config:options().
+
+-export_type([client/0]).
+-export_type([client_options/0]).
+-export_type([context/0]).
+-export_type([context_options/0]).
+
+%% Client API
+
+-spec create_client() -> client().
+create_client() ->
+    create_client(#{}).
+
+-spec create_client(client_options()) -> client().
+create_client(Options) ->
+    party_client_config:create(Options).
+
+-spec create_context() -> context().
+create_context() ->
+    create_context(#{}).
+
+-spec create_context(context_options()) -> context().
+create_context(Options) ->
+    party_client_context:create(Options).
+
+-spec child_spec(atom(), client()) -> supervisor:child_spec().
+child_spec(ChildID, Client) ->
+    party_client_woody:child_spec(ChildID, Client).
+
+-spec start_link(client()) -> genlib_gen:start_ret().
+start_link(Client) ->
+    party_client_woody:start_link(Client).

apps/party_client/src/party_client_config.erl

@@ -0,0 +1,133 @@
+-module(party_client_config).
+
+-export([create/1]).
+-export([get_party_service/1]).
+-export([get_cache_mode/1]).
+-export([get_aggressive_caching_timeout/1]).
+-export([get_woody_options/1]).
+-export([get_deadline_timeout/1]).
+-export([get_retries/1]).
+
+-opaque client() :: options().
+
+-type options() :: #{
+    party_service => woody_service(),
+    aggressive_caching_timeout => timeout(),
+    woody_options => map(),
+    deadline_timeout => timeout(),
+    retries => retries()
+}.
+
+-type cache_mode() :: disabled | safe | aggressive.
+-type retries() :: #{'_' | woody:func() => genlib_retry:strategy()}.
+
+-export_type([client/0]).
+-export_type([options/0]).
+-export_type([cache_mode/0]).
+-export_type([retries/0]).
+
+-define(APPLICATION, party_client).
+-define(DEFAULT_CACHE_NAME, party_client_default_cache).
+-define(DEFAULT_WORKERS_NAME, party_client_default_workers).
+-define(DEFAULT_AGGERSSIVE_CACHING_TIMEOUT, 30000).
+-define(DEFAULT_CACHE_MODE, safe).
+-define(DEFAULT_DEADLINE_TIMEOUT, infinity).
+
+%% Internal types
+
+-type config_path() :: atom() | [atom() | [any()]].
+-type woody_service() :: woody:service().
+-type woody_options() :: woody_caching_client:options().
+
+%% API
+
+-spec create(options()) -> client().
+create(Options) ->
+    Options.
+
+-spec get_party_service(client()) -> woody:service().
+get_party_service(#{party_service := Service}) ->
+    Service;
+get_party_service(_Client) ->
+    get_default([woody, party_service], {dmsl_payproc_thrift, 'PartyManagement'}).
+
+-spec get_cache_mode(client()) -> cache_mode().
+get_cache_mode(#{cache_mode := CacheMode}) ->
+    CacheMode;
+get_cache_mode(_Client) ->
+    get_default([woody, cache_mode], ?DEFAULT_CACHE_MODE).
+
+-spec get_aggressive_caching_timeout(client()) -> timeout().
+get_aggressive_caching_timeout(#{aggressive_caching_timeout := Timeout}) ->
+    Timeout;
+get_aggressive_caching_timeout(_Client) ->
+    get_default([woody, aggressive_caching_time], ?DEFAULT_AGGERSSIVE_CACHING_TIMEOUT).
+
+-spec get_woody_options(client()) -> woody_options().
+get_woody_options(Client) ->
+    DefaultOptions = #{
+        cache => #{local_name => ?DEFAULT_CACHE_NAME},
+        workers_name => ?DEFAULT_WORKERS_NAME,
+        woody_client => #{
+            url => get_default([services, party_management]),
+            event_handler => woody_event_handler_default,
+            transport_opts => #{}
+        }
+    },
+    EnvOptions = merge_nested_maps(DefaultOptions, get_default([woody, options], #{})),
+    merge_nested_maps(EnvOptions, maps:get(woody_options, Client, #{})).
+
+-spec get_deadline_timeout(client()) -> timeout().
+get_deadline_timeout(#{deadline_timeout := Timeout}) ->
+    Timeout;
+get_deadline_timeout(_Client) ->
+    get_default([woody, deadline_timeout], ?DEFAULT_DEADLINE_TIMEOUT).
+
+-spec get_retries(client()) -> retries().
+get_retries(#{retries := Retries}) ->
+    Retries;
+get_retries(_Client) ->
+    get_default([woody, retries], #{}).
+
+%% Internal functions
+
+-spec get_default(config_path()) -> any().
+get_default(Path) ->
+    Ref = erlang:make_ref(),
+    case get_default(Path, Ref) of
+        Ref ->
+            erlang:error({badpath, Path});
+        Other ->
+            Other
+    end.
+
+-spec get_default(config_path(), any()) -> any().
+get_default(Key, Default) when is_atom(Key) ->
+    genlib_app:env(?APPLICATION, Key, Default);
+get_default([Key | Rest] = Path, Default) when is_list(Path) ->
+    ConfigItem = get_default(Key, #{}),
+    get_nested_map(Rest, ConfigItem, Default).
+
+-spec get_nested_map(Path :: [any()], map(), any()) -> any().
+get_nested_map([Key], Map, Default) ->
+    maps:get(Key, Map, Default);
+get_nested_map([Key | Path], Map, Default) ->
+    NextMap = maps:get(Key, Map, Default),
+    get_nested_map(Path, NextMap, Default).
+
+merge_nested_maps(Map1, Map2) when map_size(Map2) =:= 0 ->
+    Map1;
+merge_nested_maps(Map1, Map2) ->
+    maps:fold(fun merge_map_item/3, Map1, Map2).
+
+merge_map_item(K, V, Acc) when is_map(V) ->
+    NewV =
+        case maps:is_key(K, Acc) of
+            true ->
+                merge_nested_maps(maps:get(K, Acc), V);
+            false ->
+                V
+        end,
+    Acc#{K => NewV};
+merge_map_item(K, V, Acc) ->
+    Acc#{K => V}.

apps/party_client/src/party_client_context.erl

@@ -0,0 +1,37 @@
+-module(party_client_context).
+
+-export([create/1]).
+-export([get_woody_context/1]).
+
+-opaque context() :: #{
+    woody_context := woody_context()
+}.
+
+-type options() :: #{
+    woody_context => woody_context()
+}.
+
+-export_type([context/0]).
+-export_type([options/0]).
+
+%% Internal types
+
+-type woody_context() :: woody_context:ctx().
+
+%% API
+
+-spec create(options()) -> context().
+create(Options) ->
+    ensure_woody_context_exists(Options).
+
+-spec get_woody_context(context()) -> woody_context().
+get_woody_context(#{woody_context := WoodyContext}) ->
+    WoodyContext.
+
+%% Internal functions
+
+-spec ensure_woody_context_exists(options()) -> options().
+ensure_woody_context_exists(#{woody_context := _WoodyContext} = Options) ->
+    Options;
+ensure_woody_context_exists(Options) ->
+    Options#{woody_context => woody_context:new()}.