[Artifact 1581]リアクタープレートの作成

Asset/data/asset/functions/artifact/1581.reactor_plate/damage/1.trigger.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1581.reactor_plate/damage/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{hotbar:[1581]} run function asset:artifact/1581.reactor_plate/damage/2.check_condition

Asset/data/asset/functions/artifact/1581.reactor_plate/damage/2.check_condition.mcfunction

@@ -0,0 +1,17 @@
+#> asset:artifact/1581.reactor_plate/damage/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/1581.reactor_plate/damage/1.trigger
+
+
+# 他にアイテム等確認する場合はここに書く
+# Dotでは反応しない
+    execute if data storage asset:context Attack{IsDoT:true} run return fail
+# 特定 ID の Effect 情報を取得
+    data modify storage api: Argument.ID set value 377
+    function api:entity/mob/effect/get/from_id
+# エフェクトがないなら終わり
+    execute unless data storage api: Return.Effect run return fail
+# 3.main.mcfunctionを実行する
+    function asset:artifact/1581.reactor_plate/damage/3.main

Asset/data/asset/functions/artifact/1581.reactor_plate/damage/3.main.mcfunction

@@ -0,0 +1,31 @@
+#> asset:artifact/1581.reactor_plate/damage/3.main
+#
+# スタックに応じて暴発ダメージ(攻撃するときだけ一瞬持つように運用するのはずるいのでホットバー検知にした)
+#
+# @within function asset:artifact/1581.reactor_plate/damage/2.check_condition
+
+
+# 特定 ID の Effect 情報を取得はcheckで済み
+
+# 基礎ダメージとバフ量指定(Damage+Baf*スタック数=与ダメ)
+    scoreboard players set $17X.Damage Temporary 0
+    scoreboard players set $17X.Baf Temporary 20
+# 計算処理
+    function asset:artifact/1581.reactor_plate/trigger/calculate
+
+# 演出
+    function asset:artifact/1581.reactor_plate/damage/vfx/explode
+
+# (暴発)自爆ダメージ(計算機構でダメージ量は指定)
+    data modify storage api: Argument.AttackType set value "Physical"
+    data modify storage api: Argument.ElementType set value "Fire"
+    data modify storage api: Argument.DeathMessage append value '[{"translate":"%1$sは熱に浮かされすぎた","with":[{"selector":"@s"}]}]'
+    data modify storage api: Argument.DeathMessage append value '[{"translate":"%1$sは魔力炉の暴発に巻き込まれた","with":[{"selector":"@s"}]}]'
+    data modify storage api: Argument.FixedDamage set value true
+    function api:damage/
+    function api:damage/reset
+
+# 効果削除
+    data modify storage api: Argument.ID set value 377
+    function api:entity/mob/effect/remove/from_id
+    function api:entity/mob/effect/reset

Asset/data/asset/functions/artifact/1581.reactor_plate/damage/dis_equip/.mcfunction

@@ -0,0 +1,7 @@
+#> asset:artifact/1581.reactor_plate/damage/dis_equip/
+#
+# 装備を外した時に外した部位にのみのidが入った状態でトリガーされる
+#
+# @within tag/function asset:artifact/dis_equip
+
+execute if data storage asset:context id{hotbar:[1581]} run function asset:artifact/1581.reactor_plate/damage/dis_equip/main

Asset/data/asset/functions/artifact/1581.reactor_plate/damage/dis_equip/main.mcfunction

@@ -0,0 +1,17 @@
+#> asset:artifact/1581.reactor_plate/damage/dis_equip/main
+#
+# オフハンドに隠すと暴発を防げちゃうのでいっそ排熱されるようにする
+#
+# @within function asset:artifact/1581.reactor_plate/damage/dis_equip/
+
+# 特定 ID の Effect 情報を取得
+    data modify storage api: Argument.ID set value 377
+    function api:entity/mob/effect/get/from_id
+# スタックがないなら
+    execute unless data storage api: Return.Effect run return fail
+# 演出
+    function asset:artifact/1581.reactor_plate/damage/vfx/exhaust
+# 削除
+    data modify storage api: Argument.ID set value 377
+    function api:entity/mob/effect/remove/from_id
+    function api:entity/mob/effect/reset

Asset/data/asset/functions/artifact/1581.reactor_plate/damage/vfx/exhaust.mcfunction

@@ -0,0 +1,12 @@
+#> asset:artifact/1581.reactor_plate/damage/vfx/exhaust
+#
+# 排熱演出
+#
+# @within function asset:artifact/1581.reactor_plate/damage/dis_equip/main
+
+
+# 演出
+    playsound minecraft:block.fire.extinguish player @a ~ ~ ~ 1 0.8
+    particle minecraft:cloud ~ ~1 ~ 0.15 0.15 0.15 0.08 15 normal
+    particle minecraft:smoke ~ ~1 ~ 0.25 0.5 0.25 0.02 8 normal
+    particle minecraft:poof ~ ~1 ~ 0.15 0.15 0.15 0.04 6 normal

Asset/data/asset/functions/artifact/1581.reactor_plate/damage/vfx/explode.mcfunction

@@ -0,0 +1,13 @@
+#> asset:artifact/1581.reactor_plate/damage/vfx/explode
+#
+# 自爆演出
+#
+# @within function asset:artifact/1581.reactor_plate/damage/3.main
+
+
+# 演出
+    playsound minecraft:entity.generic.explode player @a ~ ~ ~ 2.0 0.8
+    playsound minecraft:entity.dragon_fireball.explode player @a ~ ~ ~ 2.0 1.0
+    particle minecraft:flash ~ ~1 ~ 0 0 0 0 1 normal
+    particle minecraft:explosion_emitter ~ ~1 ~ 0.5 0.5 0.5 0 1 normal
+    particle minecraft:flame ~ ~1 ~ 0.5 0.5 0.5 0.5 100 normal

Asset/data/asset/functions/artifact/1581.reactor_plate/give/1.trigger.mcfunction

@@ -0,0 +1,7 @@
+#> asset:artifact/1581.reactor_plate/give/1.trigger
+#
+# 神器の取得処理の呼び出し時に実行されるfunction
+#
+# @within tag/function asset:artifact/give
+
+execute if data storage asset:context {id:1581} run function asset:artifact/1581.reactor_plate/give/2.give

Asset/data/asset/functions/artifact/1581.reactor_plate/give/2.give.mcfunction

@@ -0,0 +1,68 @@
+#> asset:artifact/1581.reactor_plate/give/2.give
+#
+# 神器の作成部 ここでID等を定義する
+#
+# @user
+# @within function asset:artifact/1581.reactor_plate/give/1.trigger
+
+# 神器の説明や消費MPなどをここで設定する。
+# 最後にasset:artifact/common/giveを実行することで入手可能。
+
+# 神器のID (int) スプレッドシートの値を入れる
+    data modify storage asset:artifact ID set value 1581
+# 神器のベースアイテム
+    data modify storage asset:artifact Item set value "stick"
+# 神器の名前 (TextComponentString)
+    data modify storage asset:artifact Name set value '{"text":"リアクタープレート","color":"#B52400","bold":true}'
+# 神器の説明文 (TextComponentString[])
+    data modify storage asset:artifact Lore set value ['{"translate":"-%1$s攻撃時、チャージを1段階得る(最大%2$s段階)","with":[{"text":"\\u0002","font":"space"},{"text":"10"}]}','[{"translate":"-%1$sチャージ段階に応じてダメージが上昇する","with":[{"text":"\\u0002","font":"space"}]}]','[{"translate":"-%1$sクリティカル攻撃時、チャージを全て消費して範囲攻撃を行う","color":"white","with":[{"text":"\\u0002","font":"space"}]}]','[{"translate":"%1$s-%2$s最大チャージ時は敵の耐性を無視する","color":"white","with":[{"text":"\\u0008","font":"space"},{"text":"\\u0002","font":"space"}]}]','[{"translate":"-%1$s被ダメージ時、チャージがリセットされる","color":"white","with":[{"text":"\\u0002","font":"space"}]}]','[{"translate":"%1$s-%2$sチャージ1段階につき最大体力の%3$s分のダメージを受ける","color":"white","with":[{"text":"\\u0008","font":"space"},{"text":"\\u0002","font":"space"},{"text":"10%"}]}]']
+# 消費アイテム ({Item: TextComponent, Count: int, Extra?: TextComponent}) (オプション)
+    # data modify storage asset:artifact ConsumeItem.Item set value '{"translate":"item.minecraft.stick"}'
+    # data modify storage asset:artifact ConsumeItem.Count set value 1
+    # data modify storage asset:artifact ConsumeItem.Extra set value
+# 使用回数 (int) (オプション)
+    # data modify storage asset:artifact RemainingCount set value
+# 神器を発動できるスロット (string) Wikiを参照
+    data modify storage asset:artifact Slot set value "mainhand"
+# 神器のトリガー (string) Wikiを参照
+    data modify storage asset:artifact Trigger set value "onAttackByMelee"
+# 神器の発動条件 (TextComponentString) (オプション)
+    # data modify storage asset:artifact Condition set value
+# 攻撃に関する情報 -Damage量 (literal[]/literal) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.Damage set value "500-1000 / 400-5600"
+# 攻撃に関する情報 -攻撃タイプ (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.AttackType set value [Physical]
+# 攻撃に関する情報 -攻撃属性 (string[]) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.ElementType set value [Fire]
+# 攻撃に関する情報 -防御無視 (boolean) Wikiを参照 (オプション)
+    # data modify storage asset:artifact AttackInfo.BypassResist set value
+# 攻撃に関する情報 -範囲攻撃 (string) Wikiを参照 (オプション)
+    data modify storage asset:artifact AttackInfo.IsRangeAttack set value "condition"
+# 攻撃に関する情報 -攻撃範囲 (literal) Wikiを参照 (オプション)
+    #data modify storage asset:artifact AttackInfo.AttackRange set value
+# MP消費量 (int)
+    data modify storage asset:artifact MPCost set value 40
+# MP必要量 (int) (オプション)
+    # data modify storage asset:artifact MPRequire set value
+# MP回復量 (int)
+    # data modify storage asset:artifact MPHealWhenHit set value
+# 神器のクールダウン (int) (オプション)
+    #data modify storage asset:artifact LocalCooldown set value
+# 種別クールダウン ({Type: string, Duration: int}) (オプション)
+    data modify storage asset:artifact TypeCooldown.Type set value "shortRange"
+    data modify storage asset:artifact TypeCooldown.Duration set value 12
+# グローバルクールダウン (int) (オプション)
+    # data modify storage asset:artifact SpecialCooldown set value
+# クールダウンによる使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableCooldownMessage set value
+# MP不足による使用不可のメッセージを非表示にするか否か (boolean) (オプション)
+    # data modify storage asset:artifact DisableMPMessage set value
+# 破壊時の音を鳴らさないかどうか (boolean) (オプション)
+    # data modify storage asset:artifact DisableBreakSound set value
+# 扱える神 (string[]) Wikiを参照
+    data modify storage asset:artifact CanUsedGod set value ["Urban", "Rumor"]
+# カスタムNBT (NBTCompound) 追加で指定したいNBT (オプション)
+    # data modify storage asset:artifact CustomNBT set value {}
+
+# 神器の入手用function
+    function asset:artifact/common/give

Asset/data/asset/functions/artifact/1581.reactor_plate/register.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1581.reactor_plate/register
+#
+# 神器プールへの登録処理
+#
+# @within tag/function asset:artifact/register
+
+data modify storage asset:artifact RarityRegistry[4] append value [1581]
+data modify storage asset:artifact RarityRegistryWithColor.Red[4] append value [1581]

Asset/data/asset/functions/artifact/1581.reactor_plate/trigger/1.trigger.mcfunction

@@ -0,0 +1,8 @@
+#> asset:artifact/1581.reactor_plate/trigger/1.trigger
+#
+# 指定したイベントタイミングで実行されるfunction
+#
+# @within tag/function asset:artifact/**
+
+# storage asset:idのmainhandに装備している神器のIDが入っているので比較し、~/2.check_condition.mcfunctionを実行する
+    execute if data storage asset:context id{mainhand:1581} run function asset:artifact/1581.reactor_plate/trigger/2.check_condition

Asset/data/asset/functions/artifact/1581.reactor_plate/trigger/2.check_condition.mcfunction

@@ -0,0 +1,12 @@
+#> asset:artifact/1581.reactor_plate/trigger/2.check_condition
+#
+# 神器の発動条件をチェックします
+#
+# @within function asset:artifact/1581.reactor_plate/trigger/1.trigger
+
+# 神器の基本的な条件の確認を行うfunction、成功している場合CanUsedタグが付く
+    function asset:artifact/common/check_condition/mainhand
+# 他にアイテム等確認する場合はここに書く
+
+# CanUsedタグをチェックして3.main.mcfunctionを実行する
+    execute if entity @s[tag=CanUsed] run function asset:artifact/1581.reactor_plate/trigger/3.main

Asset/data/asset/functions/artifact/1581.reactor_plate/trigger/3.main.mcfunction

@@ -0,0 +1,44 @@
+#> asset:artifact/1581.reactor_plate/trigger/3.main
+#
+# 神器のメイン処理部
+#
+# @within function asset:artifact/1581.reactor_plate/trigger/2.check_condition
+
+# 基本的な使用時の処理(MP消費や使用回数の処理など)を行う
+    function asset:artifact/common/use/mainhand
+
+# ここから先は神器側の効果の処理を書く
+
+# 特定 ID の Effect 情報を取得
+    data modify storage api: Argument.ID set value 377
+    function api:entity/mob/effect/get/from_id
+# クリティカルかつスタックがあるなら特殊攻撃に分岐
+    execute if data storage asset:context Attack{Crit:true} if data storage api: Return.Effect run return run function asset:artifact/1581.reactor_plate/trigger/crit
+
+# 基礎ダメージとバフ量指定(Damage+Baf*スタック数=与ダメ)
+    scoreboard players set $17X.Damage Temporary 500
+    scoreboard players set $17X.Baf Temporary 50
+
+# 計算処理
+    function asset:artifact/1581.reactor_plate/trigger/calculate
+
+# 演出
+    execute at @e[type=#lib:living_without_player,tag=Victim,tag=!Uninterferable,distance=..10] run function asset:artifact/1581.reactor_plate/trigger/vfx/normal
+    execute anchored eyes positioned ^ ^ ^1.3 positioned ~ ~-0.5 ~ run function asset:artifact/1581.reactor_plate/trigger/vfx/normal_slash
+
+# ダメージ(計算機構でダメージ量は指定)
+    data modify storage api: Argument.AttackType set value "Physical"
+    data modify storage api: Argument.ElementType set value "Fire"
+    function api:damage/modifier
+    execute as @e[type=#lib:living_without_player,tag=Victim,tag=!Uninterferable,distance=..10] run function api:damage/
+    function api:damage/reset
+
+# スタック付与
+    data modify storage api: Argument.ID set value 377
+    data modify storage api: Argument.Duration set value 300
+    data modify storage api: Argument.Stack set value 1
+    data modify storage api: Argument.DurationOperation set value "forceReplace"
+    data modify storage api: Argument.StackOperation set value "add"
+    data modify storage api: Argument.FieldOverride.Damage set value 20
+    function api:entity/mob/effect/give
+    function api:entity/mob/effect/reset

Asset/data/asset/functions/artifact/1581.reactor_plate/trigger/calculate.mcfunction

@@ -0,0 +1,19 @@
+#> asset:artifact/1581.reactor_plate/trigger/calculate
+#
+# ダメージ計算
+#
+# @within function asset:artifact/1581.reactor_plate/**
+    #declare score_holder $17X.Stack
+    #declare score_holder $17X.Damage
+    #declare score_holder $17X.Baf
+
+# スタック取得
+    execute store result score $17X.Stack Temporary run data get storage api: Return.Effect.Stack
+    scoreboard players operation $17X.Stack Temporary *= $17X.Baf Temporary
+    scoreboard players operation $17X.Damage Temporary += $17X.Stack Temporary
+# ダメージ設定
+    execute store result storage api: Argument.Damage float 1 run scoreboard players get $17X.Damage Temporary
+# リセット
+    scoreboard players reset $17X.Stack Temporary
+    scoreboard players reset $17X.Damage Temporary
+    scoreboard players reset $17X.Baf Temporary

Asset/data/asset/functions/artifact/1581.reactor_plate/trigger/crit.mcfunction

@@ -0,0 +1,40 @@
+#> asset:artifact/1581.reactor_plate/trigger/crit
+#
+# スペシャル攻撃
+#
+# @within function asset:artifact/1581.reactor_plate/trigger/3.main
+#> Private
+# @private
+    #declare tag 17X.Hit
+
+# 特定 ID の Effect 情報を取得
+    data modify storage api: Argument.ID set value 377
+    function api:entity/mob/effect/get/from_id
+# 10層なら最大攻撃に
+    execute if data storage api: Return.Effect{Stack:10} run return run function asset:artifact/1581.reactor_plate/trigger/full
+
+# 基礎ダメージとバフ量指定(Damage+Baf*スタック数=与ダメ)
+    scoreboard players set $17X.Damage Temporary 0
+    scoreboard players set $17X.Baf Temporary 400
+
+# 計算処理
+    function asset:artifact/1581.reactor_plate/trigger/calculate
+
+# 演出
+    execute at @e[type=#lib:living_without_player,tag=Victim,tag=!Uninterferable,distance=..10] run function asset:artifact/1581.reactor_plate/trigger/vfx/special1
+
+# 範囲
+    execute at @e[type=#lib:living_without_player,tag=Victim,tag=!Uninterferable,distance=..10] run tag @e[type=#lib:living_without_player,tag=!Uninterferable,distance=..3] add 17X.Hit
+
+# ダメージ(計算機構でダメージ量は指定)
+    data modify storage api: Argument.AttackType set value "Physical"
+    data modify storage api: Argument.ElementType set value "Fire"
+    function api:damage/modifier
+    execute as @e[type=#lib:living_without_player,tag=17X.Hit,tag=!Uninterferable,distance=..10] run function api:damage/
+    function api:damage/reset
+
+# 効果削除
+    data modify storage api: Argument.ID set value 377
+    function api:entity/mob/effect/remove/from_id
+    function api:entity/mob/effect/reset
+    tag @e[type=#lib:living_without_player,tag=17X.Hit,tag=!Uninterferable,distance=..10] remove 17X.Hit

Asset/data/asset/functions/artifact/1581.reactor_plate/trigger/full.mcfunction

@@ -0,0 +1,31 @@
+#> asset:artifact/1581.reactor_plate/trigger/full
+#
+# スペシャル攻撃(最大チャージ)
+#
+# @within function asset:artifact/1581.reactor_plate/trigger/crit
+#> Private
+# @private
+    #declare tag 17X.Hit
+
+
+# 演出
+    execute at @e[type=#lib:living_without_player,tag=Victim,tag=!Uninterferable,distance=..10] run function asset:artifact/1581.reactor_plate/trigger/vfx/special2
+
+# 範囲
+    execute at @e[type=#lib:living_without_player,tag=Victim,tag=!Uninterferable,distance=..10] run tag @e[type=#lib:living_without_player,tag=!Uninterferable,distance=..7] add 17X.Hit
+
+# ダメージ(威力固定のため計算はなし)防御、属性貫通
+    data modify storage api: Argument.Damage set value 5600
+    data modify storage api: Argument.AttackType set value "Physical"
+    data modify storage api: Argument.ElementType set value "Fire"
+    data modify storage api: Argument.BypassArmorDefense set value true
+    function api:damage/modifier
+    data modify storage api: Argument.BypassModifier set value true
+    execute as @e[type=#lib:living_without_player,tag=17X.Hit,tag=!Uninterferable,distance=..10] run function api:damage/
+    function api:damage/reset
+
+# スタック削除
+    data modify storage api: Argument.ID set value 377
+    function api:entity/mob/effect/remove/from_id
+    function api:entity/mob/effect/reset
+    tag @e[type=#lib:living_without_player,tag=17X.Hit,tag=!Uninterferable,distance=..10] remove 17X.Hit

Asset/data/asset/functions/artifact/1581.reactor_plate/trigger/vfx/normal.mcfunction

@@ -0,0 +1,11 @@
+#> asset:artifact/1581.reactor_plate/trigger/vfx/normal
+#
+# 攻撃演出
+#
+# @within function asset:artifact/1581.reactor_plate/trigger/3.main
+
+    playsound minecraft:entity.blaze.hurt player @a ~ ~ ~ 1.2 0.8
+    playsound minecraft:item.firecharge.use player @a ~ ~ ~ 0.4 1.5
+    playsound minecraft:block.respawn_anchor.charge player @a ~ ~ ~ 0.7 1.8
+    particle minecraft:lava ~ ~1 ~ 0.5 0.5 0.5 1.0 10 normal
+    particle minecraft:smoke ~ ~1 ~ 0.3 0.5 0.3 0.01 5 normal

Asset/data/asset/functions/artifact/1581.reactor_plate/trigger/vfx/normal_slash.mcfunction

@@ -0,0 +1,11 @@
+#> asset:artifact/1581.reactor_plate/trigger/vfx/normal_slash
+#
+# 攻撃演出
+#
+# @within function asset:artifact/1581.reactor_plate/trigger/3.main
+
+
+    # 斬撃
+    data modify storage api: Argument.ID set value 2001
+    data modify storage api: Argument.FieldOverride set value {Color:16729344,Frames:[20335,20336,20337],Scale:[3f,3f,0.1f],Transformation:{left_rotation:[0.561f,-0.43f,0.43f,0.561f],right_rotation:[0f,0f,0f,1f],translation:[0f,0f,0f]}}
+    function api:object/summon